From cbb2d18426c70d34c61f56099a4fa664af57e6b8 Mon Sep 17 00:00:00 2001
From: Vasil Zlatanov <v@skozl.com>
Date: Tue, 31 Mar 2020 11:55:50 +0100
Subject: ssh-agent by by default
---
Shell/bash_aliases | 3 +-
Shell/ssh-agent.plugin.zsh | 82 ++++++++++++++++++++++++++++++++++++++++++++++
Shell/zshrc | 1 +
3 files changed, 85 insertions(+), 1 deletion(-)
create mode 100644 Shell/ssh-agent.plugin.zsh
(limited to 'Shell')
diff --git a/Shell/bash_aliases b/Shell/bash_aliases
index ce4dbcc..c5d52f7 100644
--- a/Shell/bash_aliases
+++ b/Shell/bash_aliases
@@ -1,6 +1,7 @@
#if you wanna change timezone just copy one of /usr/share/zoneinfo/place to /etc/localtime
-alias ssh='kitty +kitten ssh'
+alias ssh='kitty +kitten ssh -Y'
+alias vim='nvim'
#bauerbill
alias bb='baurebill'
diff --git a/Shell/ssh-agent.plugin.zsh b/Shell/ssh-agent.plugin.zsh
new file mode 100644
index 0000000..313fe77
--- /dev/null
+++ b/Shell/ssh-agent.plugin.zsh
@@ -0,0 +1,82 @@
+typeset _agent_forwarding _ssh_env_cache
+
+function _start_agent() {
+ local lifetime
+ zstyle -s :omz:plugins:ssh-agent lifetime lifetime
+
+ # start ssh-agent and setup environment
+ echo Starting ssh-agent...
+ ssh-agent -s ${lifetime:+-t} ${lifetime} | sed 's/^echo/#echo/' >! $_ssh_env_cache
+ chmod 600 $_ssh_env_cache
+ . $_ssh_env_cache > /dev/null
+}
+
+function _add_identities() {
+ local id line sig lines
+ local -a identities loaded_sigs loaded_ids not_loaded
+ zstyle -a :omz:plugins:ssh-agent identities identities
+
+ # check for .ssh folder presence
+ if [[ ! -d $HOME/.ssh ]]; then
+ return
+ fi
+
+ # add default keys if no identities were set up via zstyle
+ # this is to mimic the call to ssh-add with no identities
+ if [[ ${#identities} -eq 0 ]]; then
+ # key list found on `ssh-add` man page's DESCRIPTION section
+ for id in id_rsa id_dsa id_ecdsa id_ed25519 identity id_rsa_work; do
+ # check if file exists
+ [[ -f "$HOME/.ssh/$id" ]] && identities+=$id
+ done
+ fi
+
+ # get list of loaded identities' signatures and filenames
+ if lines=$(ssh-add -l); then
+ for line in ${(f)lines}; do
+ loaded_sigs+=${${(z)line}[2]}
+ loaded_ids+=${${(z)line}[3]}
+ done
+ fi
+
+ # add identities if not already loaded
+ for id in $identities; do
+ # check for filename match, otherwise try for signature match
+ if [[ ${loaded_ids[(I)$HOME/.ssh/$id]} -le 0 ]]; then
+ sig="$(ssh-keygen -lf "$HOME/.ssh/$id" | awk '{print $2}')"
+ [[ ${loaded_sigs[(I)$sig]} -le 0 ]] && not_loaded+="$HOME/.ssh/$id"
+ fi
+ done
+
+ [[ -n "$not_loaded" ]] && ssh-add ${^not_loaded}
+}
+
+# Get the filename to store/lookup the environment from
+_ssh_env_cache="$HOME/.ssh/environment-$SHORT_HOST"
+
+# test if agent-forwarding is enabled
+zstyle -b :omz:plugins:ssh-agent agent-forwarding _agent_forwarding
+
+if [[ $_agent_forwarding == "yes" && -n "$SSH_AUTH_SOCK" ]]; then
+ # Add a nifty symlink for screen/tmux if agent forwarding
+ [[ -L $SSH_AUTH_SOCK ]] || ln -sf "$SSH_AUTH_SOCK" /tmp/ssh-agent-$USER-screen
+elif [[ -f "$_ssh_env_cache" ]]; then
+ # Source SSH settings, if applicable
+ . $_ssh_env_cache > /dev/null
+ if [[ $USER == "root" ]]; then
+ FILTER="ax"
+ else
+ FILTER="x"
+ fi
+ ps $FILTER | grep ssh-agent | grep -q $SSH_AGENT_PID || {
+ _start_agent
+ }
+else
+ _start_agent
+fi
+
+_add_identities
+
+# tidy up after ourselves
+unset _agent_forwarding _ssh_env_cache
+unfunction _start_agent _add_identities
diff --git a/Shell/zshrc b/Shell/zshrc
index 2e2854c..25d338a 100644
--- a/Shell/zshrc
+++ b/Shell/zshrc
@@ -86,3 +86,4 @@ bindkey '^[[1;5D' emacs-backward-word
source /usr/share/fzf/key-bindings.zsh
source ~/dotfiles/Shell/forgit.plugin.zsh
+source ~/dotfiles/Shell/ssh-agent.plugin.zsh
--
cgit v1.2.3-70-g09d2